图一

    首先，我们先对相关理论知识进行一番了解，可以看到图1中有8位数码管，那么这些数码管是怎样来显示1，2，3，4……数字的呢？别着急，我们一起慢慢来学。
    数码管实际上是由7个发光管组成“8”字形构成的，加上小数点就是8个。这些段分别由字母a,b,c,d,e,f,g,dp来表示。当数码管特定的段加上电压后，这些特定的段就会发亮，以形成我们眼睛看到的字样了。如：显示一个“2”字，那么应当是a亮b亮g亮e亮d亮f不亮c不亮dp不亮。
7段数码管的段排列和内结构见图2:

图二

    SP-28USB学习系统用的是共阳极数码管。所谓共阳极就是它们的公共端接正极；还有一种是共阴极数码管，即公共端是接负极的。
可以看到学习系统上有8个数码管，那我们应该如何来控制哪一只数码管作显示呢？再看看板上的图片，数码管上面有8个黑色三极管，对，就是用它们来控制哪个数码管亮的。

   数码管电路部分的硬件原理图如图3所示。

图三
　

先在记事本里写好下列程序,(随机套件光盘里也有,可以直接调用)保存为:ASM文件.

CODE_SEG SEGMENT CODE

DATA_SEG SEGMENT DATA

RSEG DATA_SEG

dis_digit: DS 1
dis_index: DS 1
dis_buf: DS 8
stack: DS 20

;===========================================================

CSEG AT 00000H ; Reset向量
LJMP MAIN

CSEG AT 0000BH ; 定时器0中断向量

LJMP TIMER0


;===========================================================
RSEG CODE_SEG
MAIN:
MOV SP,#(stack-1) ; 初始化堆栈指针
MOV P0,#0FFH ; 初始化I/O口
MOV P2,#0FFH
MOV TMOD,#01H ; 初始化timer0
MOV TH0,#0FCH
MOV TL0,#017H
MOV IE,#082H

MOV DPTR, #DIS_CODE ; 设定显示初值
MOV A,#1
MOVC A,@A+DPTR
MOV dis_buf,A
MOV A,#2
MOVC A,@A+DPTR
MOV dis_buf+01H,A
MOV A,#3
MOVC A,@A+DPTR
MOV dis_buf+02H,A
MOV A,#4
MOVC A,@A+DPTR
MOV dis_buf+03H,A
MOV A,#5
MOVC A,@A+DPTR
MOV dis_buf+04H,A
MOV A,#6
MOVC A,@A+DPTR
MOV dis_buf+05H,A
MOV A,#7
MOVC A,@A+DPTR
MOV dis_buf+06H,A
MOV A,#8
MOVC A,@A+DPTR
MOV dis_buf+07H,A

MOV dis_digit,#0FEH ; 初始从第一个数码管开始扫描
MOV dis_index,A

SETB TR0 ; 启动定时器0，开始动态扫描显示

MAIN_LP:

; 主程序循环，增加其它代码

SJMP MAIN_LP

; END OF main


;===========================================================

USING 0
TIMER0:
; 定时器0中断服程序, 用于数码管的动态扫描
; DIS_INDEX --- 显示索引, 用于标识当前显示的数码管和缓冲区的偏移量
; DIS_DIGIT --- 位选通值, 传送到P2口用于选通当前数码管的数值, 如等于0xfe时,
; 选通P2.0口数码管
; DIS_BUF --- 显于缓冲区基地址

PUSH ACC
PUSH PSW
PUSH AR0

MOV TH0,#0FCH
MOV TL0,#017H

MOV P2,#0FFH ; 先关闭所有数码管

MOV A,#DIS_BUF ; 获得显示缓冲区基地址
ADD A,DIS_INDEX ; 获得偏移量
MOV R0,A ; R0 = 基地址 + 偏移量
MOV A,@R0 ; 获得显示代码
MOV P0,A ; 显示代码传送到P0口

MOV P2,DIS_DIGIT ;

MOV A,DIS_DIGIT ; 位选通值左移, 下次中断时选通下一位数码管
RL A
MOV DIS_DIGIT,A

INC DIS_INDEX ; DIS_INDEX加1, 下次中断时显示下一位
ANL DIS_INDEX,#0x07 ; 当DIS_INDEX等于8(0000 1000)时, 清0

POP AR0
POP PSW
POP ACC

RETI
; END OF timer0
;===========================================================

RSEG CODE_SEG
DIS_CODE:
DB 0C0H
DB 0F9H
DB 0A4H
DB 0B0H
DB 099H
DB 092H
DB 082H
DB 0F8H
DB 080H
DB 090H
DB 0FFH

END

下来我们通过Keil51将上面文件编译,生成hex文件(光盘里有)

    接下来我们就需要大开SP-28USB烧写软件,选择AT89S51芯片,调入要烧写的程序文件，执行“调入flash”，找到刚才我们刚才已经准备好的my.hex文件，选中打开即可。然后，我们执行一下“擦除”操作，差不多1秒钟即可完成芯片的擦除工作，速度很快。好了，现在已经到最后一步了，用鼠标点一下“自动完成”按钮吧，OK，大功告成。至此，我们已经完成了从软件编写，直到烧写芯片的全部步骤。现在学习系统已可以完全脱离电脑而独立工作了,如图7所示，